/usr/share/perl5/Dist/Zilla/Plugin/MetaYAML.pm is in libdist-zilla-perl 5.043-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 | package Dist::Zilla::Plugin::MetaYAML;
# ABSTRACT: produce a META.yml
$Dist::Zilla::Plugin::MetaYAML::VERSION = '5.043';
use Moose;
with 'Dist::Zilla::Role::FileGatherer';
use Try::Tiny;
use namespace::autoclean;
#pod =head1 DESCRIPTION
#pod
#pod This plugin will add a F<META.yml> file to the distribution.
#pod
#pod For more information on this file, see L<Module::Build::API> and L<CPAN::Meta>.
#pod
#pod =attr filename
#pod
#pod If given, parameter allows you to specify an alternate name for the generated
#pod file. It defaults, of course, to F<META.yml>.
#pod
#pod =cut
has filename => (
is => 'ro',
isa => 'Str',
default => 'META.yml',
);
#pod =attr version
#pod
#pod This parameter lets you pick what version of the spec to use when generating
#pod the output. It defaults to 1.4, the most commonly supported version at
#pod present.
#pod
#pod B<This may change without notice in the future.>
#pod
#pod Once version 2 of the META file spec is more widely supported, this may default
#pod to 2.
#pod
#pod =cut
has version => (
is => 'ro',
isa => 'Num',
default => '1.4',
);
sub gather_files {
my ($self, $arg) = @_;
require Dist::Zilla::File::FromCode;
require YAML::Tiny;
require CPAN::Meta::Converter;
CPAN::Meta::Converter->VERSION(2.101550); # improved downconversion
require CPAN::Meta::Validator;
CPAN::Meta::Validator->VERSION(2.101550); # improved downconversion
my $zilla = $self->zilla;
my $file = Dist::Zilla::File::FromCode->new({
name => $self->filename,
code_return_type => 'text',
code => sub {
my $distmeta = $zilla->distmeta;
my $validator = CPAN::Meta::Validator->new($distmeta);
unless ($validator->is_valid) {
my $msg = "Invalid META structure. Errors found:\n";
$msg .= join( "\n", $validator->errors );
$self->log_fatal($msg);
}
my $converter = CPAN::Meta::Converter->new($distmeta);
my $output = $converter->convert(version => $self->version);
my $yaml = try {
YAML::Tiny->new($output)->write_string; # text!
}
catch {
$self->log_fatal("Could not create YAML string: " . YAML::Tiny->errstr)
};
return $yaml;
},
});
$self->add_file($file);
return;
}
__PACKAGE__->meta->make_immutable;
1;
#pod =head1 SEE ALSO
#pod
#pod Core Dist::Zilla plugins:
#pod L<@Basic|Dist::Zilla::PluginBundle::Basic>,
#pod L<Manifest|Dist::Zilla::Plugin::Manifest>.
#pod
#pod Dist::Zilla roles:
#pod L<FileGatherer|Dist::Zilla::Role::FileGatherer>.
#pod
#pod Other modules:
#pod L<CPAN::Meta>,
#pod L<CPAN::Meta::Spec>, L<YAML>.
#pod
#pod =cut
__END__
=pod
=encoding UTF-8
=head1 NAME
Dist::Zilla::Plugin::MetaYAML - produce a META.yml
=head1 VERSION
version 5.043
=head1 DESCRIPTION
This plugin will add a F<META.yml> file to the distribution.
For more information on this file, see L<Module::Build::API> and L<CPAN::Meta>.
=head1 ATTRIBUTES
=head2 filename
If given, parameter allows you to specify an alternate name for the generated
file. It defaults, of course, to F<META.yml>.
=head2 version
This parameter lets you pick what version of the spec to use when generating
the output. It defaults to 1.4, the most commonly supported version at
present.
B<This may change without notice in the future.>
Once version 2 of the META file spec is more widely supported, this may default
to 2.
=head1 SEE ALSO
Core Dist::Zilla plugins:
L<@Basic|Dist::Zilla::PluginBundle::Basic>,
L<Manifest|Dist::Zilla::Plugin::Manifest>.
Dist::Zilla roles:
L<FileGatherer|Dist::Zilla::Role::FileGatherer>.
Other modules:
L<CPAN::Meta>,
L<CPAN::Meta::Spec>, L<YAML>.
=head1 AUTHOR
Ricardo SIGNES <rjbs@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2016 by Ricardo SIGNES.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|