/usr/share/common-lisp/source/clsql-postgresql/db-postgresql/postgresql-sql.lisp is in cl-sql-postgresql 6.5.0-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 | ;;;; -*- Mode: LISP; Syntax: ANSI-Common-Lisp; Base: 10 -*-
;;;; *************************************************************************
;;;; FILE IDENTIFICATION
;;;;
;;;; Name: postgresql-sql.lisp
;;;; Purpose: High-level PostgreSQL interface using UFFI
;;;; Date Started: Feb 2002
;;;;
;;;; CLSQL users are granted the rights to distribute and use this software
;;;; as governed by the terms of the Lisp Lesser GNU Public License
;;;; (http://opensource.franz.com/preamble.html), also known as the LLGPL.
;;;; *************************************************************************
(in-package #:cl-user)
(defpackage #:clsql-postgresql
(:use #:common-lisp #:clsql-sys #:pgsql #:clsql-uffi)
(:export #:postgresql-database)
(:documentation "This is the CLSQL interface to PostgreSQL."))
(in-package #:clsql-postgresql)
;;; Field conversion functions
(defun make-type-list-for-auto (num-fields res-ptr)
(let ((new-types '()))
(dotimes (i num-fields)
(declare (fixnum i))
(let* ((type (PQftype res-ptr i)))
(push
(case type
((#.pgsql-ftype#bytea
#.pgsql-ftype#int2
#.pgsql-ftype#int4)
:int32)
(#.pgsql-ftype#int8
:int64)
((#.pgsql-ftype#float4
#.pgsql-ftype#float8)
:double)
(otherwise
t))
new-types)))
(nreverse new-types)))
(defun canonicalize-types (types num-fields res-ptr)
(if (null types)
nil
(let ((auto-list (make-type-list-for-auto num-fields res-ptr)))
(cond
((listp types)
(canonicalize-type-list types auto-list))
((eq types :auto)
auto-list)
(t
nil)))))
(defun tidy-error-message (message &optional encoding)
(unless (stringp message)
(setq message (uffi:convert-from-foreign-string message :encoding encoding)))
(let ((message (string-right-trim '(#\Return #\Newline) message)))
(cond
((< (length message) (length "ERROR:"))
message)
((string= message "ERROR:" :end1 6)
(string-left-trim '(#\Space) (subseq message 6)))
(t
message))))
(defmethod database-initialize-database-type ((database-type
(eql :postgresql)))
t)
(uffi:def-type pgsql-conn-def pgsql-conn)
(uffi:def-type pgsql-result-def pgsql-result)
(defclass postgresql-database (generic-postgresql-database)
((conn-ptr :accessor database-conn-ptr :initarg :conn-ptr
:type pgsql-conn-def)
(lock
:accessor database-lock
:initform (make-process-lock "conn"))))
(defmethod database-type ((database postgresql-database))
:postgresql)
(defmethod database-name-from-spec (connection-spec (database-type
(eql :postgresql)))
(check-connection-spec connection-spec database-type
(host db user password &optional port options tty))
(destructuring-bind (host db user password &optional port options tty)
connection-spec
(declare (ignore password options tty))
(concatenate 'string
(etypecase host
(null "localhost")
(pathname (namestring host))
(string host))
(when port
(concatenate 'string
":"
(etypecase port
(integer (write-to-string port))
(string port))))
"/" db "/" user)))
(defmethod database-connect (connection-spec (database-type (eql :postgresql)))
(check-connection-spec connection-spec database-type
(host db user password &optional port options tty))
(destructuring-bind (host db user password &optional port options tty)
connection-spec
(uffi:with-cstrings ((host-native host)
(user-native user)
(password-native password)
(db-native db)
(port-native port)
(options-native options)
(tty-native tty))
(let ((connection (PQsetdbLogin host-native port-native
options-native tty-native
db-native user-native
password-native)))
(declare (type pgsql-conn-def connection))
(when (not (eq (PQstatus connection)
pgsql-conn-status-type#connection-ok))
(let ((pqstatus (PQstatus connection))
(pqmessage (tidy-error-message (PQerrorMessage connection))))
(PQfinish connection)
(error 'sql-connection-error
:database-type database-type
:connection-spec connection-spec
:error-id pqstatus
:message pqmessage)))
(make-instance 'postgresql-database
:name (database-name-from-spec connection-spec
database-type)
:database-type :postgresql
:connection-spec connection-spec
:conn-ptr connection)))))
(defmethod database-disconnect ((database postgresql-database))
(PQfinish (database-conn-ptr database))
(setf (database-conn-ptr database) nil)
t)
(defmethod database-query (query-expression (database postgresql-database) result-types field-names)
(let ((conn-ptr (database-conn-ptr database)))
(declare (type pgsql-conn-def conn-ptr))
(uffi:with-cstring (query-native query-expression)
(let ((result (PQexec conn-ptr query-native)))
(when (uffi:null-pointer-p result)
(error 'sql-database-data-error
:database database
:expression query-expression
:message (tidy-error-message (PQerrorMessage conn-ptr) (encoding database))))
(unwind-protect
(case (PQresultStatus result)
;; User gave a command rather than a query
(#.pgsql-exec-status-type#command-ok
nil)
(#.pgsql-exec-status-type#empty-query
nil)
(#.pgsql-exec-status-type#tuples-ok
(let ((num-fields (PQnfields result)))
(when result-types
(setq result-types
(canonicalize-types result-types num-fields
result)))
(let ((res (loop for tuple-index from 0 below (PQntuples result)
collect
(loop for i from 0 below num-fields
collect
(if (zerop (PQgetisnull result tuple-index i))
(convert-raw-field
(PQgetvalue result tuple-index i)
(nth i result-types)
:encoding (encoding database))
nil)))))
(if field-names
(values res (result-field-names num-fields result))
res))))
(t
(error 'sql-database-data-error
:database database
:expression query-expression
:error-id (PQresultErrorField result +PG-DIAG-SQLSTATE+)
:message (tidy-error-message
(PQresultErrorMessage result)
(encoding database)))))
(PQclear result))))))
(defun result-field-names (num-fields result)
"Return list of result field names."
(let ((names '()))
(dotimes (i num-fields (nreverse names))
(declare (fixnum i))
(push (uffi:convert-from-cstring (PQfname result i)) names))))
(defmethod database-execute-command (sql-expression
(database postgresql-database))
(let ((conn-ptr (database-conn-ptr database)))
(declare (type pgsql-conn-def conn-ptr))
(uffi:with-cstring (sql-native sql-expression)
(let ((result (PQexec conn-ptr sql-native)))
(when (uffi:null-pointer-p result)
(error 'sql-database-data-error
:database database
:expression sql-expression
:message (tidy-error-message (PQerrorMessage conn-ptr)
(encoding database))))
(unwind-protect
(case (PQresultStatus result)
(#.pgsql-exec-status-type#command-ok
t)
((#.pgsql-exec-status-type#empty-query
#.pgsql-exec-status-type#tuples-ok)
(warn "Strange result...")
t)
(t
(error 'sql-database-data-error
:database database
:expression sql-expression
:error-id (PQresultErrorField result +PG-DIAG-SQLSTATE+)
:message (tidy-error-message
(PQresultErrorMessage result)
(encoding database)))))
(PQclear result))))))
(defstruct postgresql-result-set
(res-ptr (uffi:make-null-pointer 'pgsql-result)
:type pgsql-result-def)
(types nil)
(num-tuples 0 :type integer)
(num-fields 0 :type integer)
(tuple-index 0 :type integer))
(defmethod database-query-result-set ((query-expression string)
(database postgresql-database)
&key full-set result-types)
(let ((conn-ptr (database-conn-ptr database)))
(declare (type pgsql-conn-def conn-ptr))
(uffi:with-cstring (query-native query-expression)
(let ((result (PQexec conn-ptr query-native)))
(when (uffi:null-pointer-p result)
(error 'sql-database-data-error
:database database
:expression query-expression
:message (tidy-error-message (PQerrorMessage conn-ptr)
(encoding database))))
(case (PQresultStatus result)
((#.pgsql-exec-status-type#empty-query
#.pgsql-exec-status-type#tuples-ok)
(let ((result-set (make-postgresql-result-set
:res-ptr result
:num-fields (PQnfields result)
:num-tuples (PQntuples result)
:types (canonicalize-types
result-types
(PQnfields result)
result))))
(if full-set
(values result-set
(PQnfields result)
(PQntuples result))
(values result-set
(PQnfields result)))))
(t
(unwind-protect
(error 'sql-database-data-error
:database database
:expression query-expression
:error-id (PQresultErrorField result +PG-DIAG-SQLSTATE+)
:message (tidy-error-message
(PQresultErrorMessage result)
(encoding database)))
(PQclear result))))))))
(defmethod database-dump-result-set (result-set (database postgresql-database))
(let ((res-ptr (postgresql-result-set-res-ptr result-set)))
(declare (type pgsql-result-def res-ptr))
(PQclear res-ptr)
t))
(defmethod database-store-next-row (result-set (database postgresql-database)
list)
(let ((result (postgresql-result-set-res-ptr result-set))
(types (postgresql-result-set-types result-set)))
(declare (type pgsql-result-def result))
(if (>= (postgresql-result-set-tuple-index result-set)
(postgresql-result-set-num-tuples result-set))
nil
(loop with tuple-index = (postgresql-result-set-tuple-index result-set)
for i from 0 below (postgresql-result-set-num-fields result-set)
for rest on list
do
(setf (car rest)
(if (zerop (PQgetisnull result tuple-index i))
(convert-raw-field
(PQgetvalue result tuple-index i)
(nth i types)
:encoding (encoding database))
nil))
finally
(incf (postgresql-result-set-tuple-index result-set))
(return list)))))
;;; Large objects support (Marc B)
(defmethod database-create-large-object ((database postgresql-database))
(lo-create (database-conn-ptr database)
(logior pgsql::+INV_WRITE+ pgsql::+INV_READ+)))
#+mb-original
(defmethod database-write-large-object (object-id (data string) (database postgresql-database))
(let ((ptr (database-conn-ptr database))
(length (length data))
(result nil)
(fd nil))
(with-transaction (:database database)
(unwind-protect
(progn
(setf fd (lo-open ptr object-id pgsql::+INV_WRITE+))
(when (>= fd 0)
(when (= (lo-write ptr fd data length) length)
(setf result t))))
(progn
(when (and fd (>= fd 0))
(lo-close ptr fd))
)))
result))
(defmethod database-write-large-object (object-id (data string) (database postgresql-database))
(let ((ptr (database-conn-ptr database))
(length (length data))
(result nil)
(fd nil))
(database-execute-command "begin" database)
(unwind-protect
(progn
(setf fd (lo-open ptr object-id pgsql::+INV_WRITE+))
(when (>= fd 0)
(when (= (lo-write ptr fd data length) length)
(setf result t))))
(progn
(when (and fd (>= fd 0))
(lo-close ptr fd))
(database-execute-command (if result "commit" "rollback") database)))
result))
;; (MB) the begin/commit/rollback stuff will be removed when with-transaction wil be implemented
;; (KMR) Can't use with-transaction since that function is in high-level code
(defmethod database-read-large-object (object-id (database postgresql-database))
(let ((ptr (database-conn-ptr database))
(buffer nil)
(result nil)
(length 0)
(fd nil))
(unwind-protect
(progn
(database-execute-command "begin" database)
(setf fd (lo-open ptr object-id pgsql::+INV_READ+))
(when (>= fd 0)
(setf length (lo-lseek ptr fd 0 2))
(lo-lseek ptr fd 0 0)
(when (> length 0)
(setf buffer (uffi:allocate-foreign-string
length :unsigned t))
(when (= (lo-read ptr fd buffer length) length)
(setf result (uffi:convert-from-foreign-string
buffer :length length :null-terminated-p nil
:encoding (encoding database)))))))
(progn
(when buffer (uffi:free-foreign-object buffer))
(when (and fd (>= fd 0)) (lo-close ptr fd))
(database-execute-command (if result "commit" "rollback") database)))
result))
(defmethod database-delete-large-object (object-id (database postgresql-database))
(lo-unlink (database-conn-ptr database) object-id))
;;; Object listing
(defmethod database-create (connection-spec (type (eql :postgresql)))
(destructuring-bind (host name user password) connection-spec
(let ((database (database-connect (list host "postgres" user password)
type)))
(setf (slot-value database 'clsql-sys::state) :open)
(unwind-protect
(database-execute-command (format nil "create database ~A" name) database)
(database-disconnect database)))))
(defmethod database-destroy (connection-spec (type (eql :postgresql)))
(destructuring-bind (host name user password) connection-spec
(let ((database (database-connect (list host "postgres" user password)
type)))
(setf (slot-value database 'clsql-sys::state) :open)
(unwind-protect
(database-execute-command (format nil "drop database ~A" name) database)
(database-disconnect database)))))
(defmethod database-probe (connection-spec (type (eql :postgresql)))
(when (find (second connection-spec) (database-list connection-spec type)
:test #'string-equal)
t))
(defun %pg-database-connection (connection-spec)
(check-connection-spec connection-spec :postgresql
(host db user password &optional port options tty))
(macrolet ((coerce-string (var)
`(unless (typep ,var 'simple-base-string)
(setf ,var (coerce ,var 'simple-base-string)))))
(destructuring-bind (host db user password &optional port options tty)
connection-spec
(coerce-string db)
(coerce-string user)
(let ((connection (PQsetdbLogin host port options tty db user password)))
(declare (type pgsql::pgsql-conn-ptr connection))
(unless (eq (PQstatus connection)
pgsql-conn-status-type#connection-ok)
;; Connect failed
(error 'sql-connection-error
:database-type :postgresql
:connection-spec connection-spec
:error-id (PQstatus connection)
:message (PQerrorMessage connection)))
connection))))
(defmethod database-reconnect ((database postgresql-database))
(let ((lock (database-lock database)))
(with-process-lock (lock "Reconnecting")
(with-slots (connection-spec conn-ptr)
database
(setf conn-ptr (%pg-database-connection connection-spec))
database))))
;;; Database capabilities
(when (clsql-sys:database-type-library-loaded :postgresql)
(clsql-sys:initialize-database-type :database-type :postgresql))
|