/usr/share/gnu-smalltalk/examples/Dinner.st is in gnu-smalltalk-common 3.2.4-2.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 | "======================================================================
|
| Smalltalk dining philosophers
|
|
======================================================================"
"======================================================================
|
| Copyright 1999, 2000 Free Software Foundation, Inc.
| Written by Paolo Bonzini.
|
| This file is part of GNU Smalltalk.
|
| GNU Smalltalk is free software; you can redistribute it and/or modify it
| under the terms of the GNU General Public License as published by the Free
| Software Foundation; either version 2, or (at your option) any later version.
|
| GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
| ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
| FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
| details.
|
| You should have received a copy of the GNU General Public License along with
| GNU Smalltalk; see the file COPYING. If not, write to the Free Software
| Foundation, 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
|
======================================================================"
Object subclass: #Philosophers
instanceVariableNames: 'forks philosophers randy eating'
classVariableNames: ''
poolDictionaries: ''
category: 'Examples-Processes'!
!Philosophers class methodsFor: 'dining'!
new
self shouldNotImplement
!
new: quantity
^super new initialize: quantity
! !
!Philosophers methodsFor: 'dining'!
dine
self dine: 15
!
dine: seconds
(Delay forSeconds: seconds) wait.
philosophers do: [ :each | each terminate ].
self initialize: self size
!
leftFork: n
^forks at: n
!
rightFork: n
^n = self size
ifTrue: [ forks at: 1 ]
ifFalse: [ forks at: n + 1 ]
!
initialize: n
eating := Semaphore new.
n - 1 timesRepeat: [ eating signal ].
randy := Random new.
forks := (1 to: n) collect: [ :each | Semaphore forMutualExclusion ].
philosophers := (1 to: n) collect: [ :each | self philosopher: each ].
!
philosopher: n
| philosopherCode leftFork rightFork status |
leftFork := self leftFork: n.
rightFork := self rightFork: n.
status := 'Philosopher #', n printString, ' '.
philosopherCode := [[ true ] whileTrue: [
Transcript nextPutAll: status, 'thinks'; nl.
(Delay forMilliseconds: randy next * 2000) wait.
Transcript nextPutAll: status, 'wants to eat'; nl.
eating critical: [ "Avoid deadlock"
Transcript nextPutAll: status, 'waits for left fork'; nl.
leftFork wait.
Transcript nextPutAll: status, 'waits for right fork'; nl.
rightFork wait.
Transcript nextPutAll: status, 'eats'; nl.
(Delay forMilliseconds: randy next * 2000) wait.
leftFork signal.
rightFork signal.
].
]].
^(philosopherCode newProcess)
priority: Processor userBackgroundPriority;
name: status;
resume;
yourself
!
size
^forks size
! !
(Philosophers new: 5) dine!
|