/usr/share/perl5/Plack/Middleware/HTTPExceptions.pm is in libplack-perl 1.0033-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 | package Plack::Middleware::HTTPExceptions;
use strict;
use parent qw(Plack::Middleware);
use Plack::Util::Accessor qw(rethrow);
use Carp ();
use Try::Tiny;
use Scalar::Util 'blessed';
use HTTP::Status ();
sub prepare_app {
my $self = shift;
$self->rethrow(1) if ($ENV{PLACK_ENV} || '') eq 'development';
}
sub call {
my($self, $env) = @_;
my $res = try {
$self->app->($env);
} catch {
$self->transform_error($_, $env);
};
return $res if ref $res eq 'ARRAY';
return sub {
my $respond = shift;
my $writer;
try {
$res->(sub { return $writer = $respond->(@_) });
} catch {
if ($writer) {
Carp::cluck $_;
$writer->close;
} else {
my $res = $self->transform_error($_, $env);
$respond->($res);
}
};
};
}
sub transform_error {
my($self, $e, $env) = @_;
my($code, $message);
if (blessed $e && $e->can('as_psgi')) {
return $e->as_psgi;
}
if (blessed $e && $e->can('code')) {
$code = $e->code;
$message =
$e->can('as_string') ? $e->as_string :
overload::Method($e, '""') ? "$e" : undef;
} else {
if ($self->rethrow) {
die $e;
}
else {
$code = 500;
$env->{'psgi.errors'}->print($e);
}
}
if ($code !~ /^[3-5]\d\d$/) {
die $e; # rethrow
}
$message ||= HTTP::Status::status_message($code);
my @headers = (
'Content-Type' => 'text/plain',
'Content-Length' => length($message),
);
if ($code =~ /^3/ && (my $loc = eval { $e->location })) {
push(@headers, Location => $loc);
}
return [ $code, \@headers, [ $message ] ];
}
1;
__END__
=head1 NAME
Plack::Middleware::HTTPExceptions - Catch HTTP exceptions
=head1 SYNOPSIS
use HTTP::Exception;
my $app = sub {
# ...
HTTP::Exception::500->throw;
};
builder {
enable "HTTPExceptions", rethrow => 1;
$app;
};
=head1 DESCRIPTION
Plack::Middleware::HTTPExceptions is a PSGI middleware component to
catch exceptions from applications that can be translated into HTTP
status codes.
Your application is supposed to throw an object that implements a
C<code> method which returns the HTTP status code, such as 501 or
404. This middleware catches them and creates a valid response out of
the code. If the C<code> method returns a code that is not an HTTP
redirect or error code (3xx, 4xx, or 5xx), the exception will be
rethrown.
The exception object may also implement C<as_string> or overload
stringification to represent the text of the error. The text defaults to
the status message of the error code, such as I<Service Unavailable> for
C<503>.
Finally, the exception object may implement C<as_psgi>, and the result
of this will be returned directly as the PSGI response.
If the code is in the 3xx range and the exception implements the 'location'
method (HTTP::Exception::3xx does), the Location header will be set in the
response, so you can do redirects this way.
There are CPAN modules L<HTTP::Exception> and L<HTTP::Throwable>, and
they are perfect to throw from your application to let this middleware
catch and display, but you can also implement your own exception class
to throw.
If the thrown exception is not an object that implements either a
C<code> or an C<as_psgi> method, a 500 error will be returned, and the
exception is printed to the psgi.errors stream.
Alternatively, you can pass a true value for the C<rethrow> parameter
for this middleware, and the exception will instead be rethrown. This is
enabled by default when C<PLACK_ENV> is set to C<development>, so that
the L<StackTrace|Plack::Middleware::StackTrace> middleware can catch it
instead.
=head1 AUTHOR
Tatsuhiko Miyagawa
=head1 SEE ALSO
paste.httpexceptions L<HTTP::Exception> L<HTTP::Throwable>
=cut
|