/usr/lib/python2.7/dist-packages/pyFAI/ocl_azim_CSR.cl is in pyfai 0.10.2-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 | /*
* Project: Azimuthal regroupping OpenCL kernel for PyFAI.
* Kernel with full pixel-split using a CSR sparse matrix
*
*
* Copyright (C) 2012-2014 European Synchrotron Radiation Facility
* Grenoble, France
*
* Principal authors: J. Kieffer (kieffer@esrf.fr)
* Last revision: 10/10/2014
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
/**
* \file
* \brief OpenCL kernels for 1D azimuthal integration using CSR sparse matrix representation
*
* Constant to be provided at build time:
* WORKGROUP_SIZE
*/
/**
* \brief Performs 1d azimuthal integration with full pixel splitting based on a LUT in CSR form
*
* An image intensity value is spread across the bins according to the positions stored in the LUT.
* The lut is represented by a set of 3 arrays (coefs, row_ind, col_ptr)
* Values of 0 in the mask are processed and values of 1 ignored as per PyFAI
*
* This implementation is especially efficient on CPU where each core reads adjacent memory.
* the use of local pointer can help on the CPU.
*
* @param weights Float pointer to global memory storing the input image.
* @param coefs Float pointer to global memory holding the coefficient part of the LUT
* @param row_ind Integer pointer to global memory holding the corresponding index of the coefficient
* @param col_ptr Integer pointer to global memory holding the pointers to the coefs and row_ind for the CSR matrix
* @param do_dummy Bool/int: shall the dummy pixel be checked. Dummy pixel are pixels marked as bad and ignored
* @param dummy Float: value for bad pixels
* @param outData Float pointer to the output 1D array with the weighted histogram
* @param outCount Float pointer to the output 1D array with the unweighted histogram
* @param outMerged Float pointer to the output 1D array with the diffractogram
*
*/
__kernel void
csr_integrate( const __global float *weights,
const __global float *coefs,
const __global int *row_ind,
const __global int *col_ptr,
const int do_dummy,
const float dummy,
__global float *outData,
__global float *outCount,
__global float *outMerge
)
{
int thread_id_loc = get_local_id(0);
int bin_num = get_group_id(0); // each workgroup of size=warp is assigned to 1 bin
int2 bin_bounds;
// bin_bounds = (int2) *(col_ptr+bin_num); // cool stuff!
bin_bounds.x = col_ptr[bin_num];
bin_bounds.y = col_ptr[bin_num+1];
int bin_size = bin_bounds.y-bin_bounds.x;
float sum_data = 0.0f;
float sum_count = 0.0f;
float cd = 0.0f;
float cc = 0.0f;
float t, y;
const float epsilon = 1e-10f;
float coef, data;
int idx, k, j;
for (j=bin_bounds.x;j<bin_bounds.y;j+=WORKGROUP_SIZE)
{
k = j+thread_id_loc;
if (k < bin_bounds.y) // I don't like conditionals!!
{
coef = coefs[k];
idx = row_ind[k];
data = weights[idx];
if( (!do_dummy) || (data!=dummy) )
{
//sum_data += coef * data;
//sum_count += coef;
//Kahan summation allows single precision arithmetics with error compensation
//http://en.wikipedia.org/wiki/Kahan_summation_algorithm
y = coef*data - cd;
t = sum_data + y;
cd = (t - sum_data) - y;
sum_data = t;
y = coef - cc;
t = sum_count + y;
cc = (t - sum_count) - y;
sum_count = t;
};//end if dummy
} //end if k < bin_bounds.y
};//for j
/*
* parallel reduction
*/
// REMEMBER TO PASS WORKGROUP_SIZE AS A CPP DEF
__local float super_sum_data[WORKGROUP_SIZE];
__local float super_sum_data_correction[WORKGROUP_SIZE];
__local float super_sum_count[WORKGROUP_SIZE];
__local float super_sum_count_correction[WORKGROUP_SIZE];
float super_sum_temp = 0.0f;
int index, active_threads = WORKGROUP_SIZE;
if (bin_size < WORKGROUP_SIZE)
{
if (thread_id_loc < bin_size)
{
super_sum_data_correction[thread_id_loc] = cd;
super_sum_count_correction[thread_id_loc] = cc;
super_sum_data[thread_id_loc] = sum_data;
super_sum_count[thread_id_loc] = sum_count;
}
else
{
super_sum_data_correction[thread_id_loc] = 0.0f;
super_sum_count_correction[thread_id_loc] = 0.0f;
super_sum_data[thread_id_loc] = 0.0f;
super_sum_count[thread_id_loc] = 0.0f;
}
}
else
{
super_sum_data_correction[thread_id_loc] = cd;
super_sum_count_correction[thread_id_loc] = cc;
super_sum_data[thread_id_loc] = sum_data;
super_sum_count[thread_id_loc] = sum_count;
}
barrier(CLK_LOCAL_MEM_FENCE);
cd = 0;
cc = 0;
while (active_threads != 1)
{
active_threads /= 2;
if (thread_id_loc < active_threads)
{
index = thread_id_loc+active_threads;
cd = super_sum_data_correction[thread_id_loc] + super_sum_data_correction[index];
super_sum_temp = super_sum_data[thread_id_loc];
y = super_sum_data[index] - cd;
t = super_sum_temp + y;
super_sum_data_correction[thread_id_loc] = (t - super_sum_temp) - y;
super_sum_data[thread_id_loc] = t;
cc = super_sum_count_correction[thread_id_loc] + super_sum_count_correction[index];
super_sum_temp = super_sum_count[thread_id_loc];
y = super_sum_count[index] - cc;
t = super_sum_temp + y;
super_sum_count_correction[thread_id_loc] = (t - super_sum_temp) - y;
super_sum_count[thread_id_loc] = t;
}
barrier(CLK_LOCAL_MEM_FENCE);
}
if (thread_id_loc == 0)
{
outData[bin_num] = super_sum_data[0];
outCount[bin_num] = super_sum_count[0];
if (outCount[bin_num] > epsilon)
outMerge[bin_num] = outData[bin_num] / outCount[bin_num];
else
outMerge[bin_num] = dummy;
}
};//end kernel
/**
* \brief Performs 1d azimuthal integration with full pixel splitting based on a LUT in CSR form
*
* An image intensity value is spread across the bins according to the positions stored in the LUT.
* The lut is represented by a set of 3 arrays (coefs, row_ind, col_ptr)
* Values of 0 in the mask are processed and values of 1 ignored as per PyFAI
*
* This kernel is ment to be ran with padded data (the span of each bin must be a multiple of the workgroup size)
*
* @param weights Float pointer to global memory storing the input image.
* @param coefs Float pointer to global memory holding the coefficient part of the LUT
* @param row_ind Integer pointer to global memory holding the corresponding index of the coefficient
* @param col_ptr Integer pointer to global memory holding the pointers to the coefs and row_ind for the CSR matrix
* @param do_dummy Bool/int: shall the dummy pixel be checked. Dummy pixel are pixels marked as bad and ignored
* @param dummy Float: value for bad pixels
* @param outData Float pointer to the output 1D array with the weighted histogram
* @param outCount Float pointer to the output 1D array with the unweighted histogram
* @param outMerged Float pointer to the output 1D array with the diffractogram
*
*/
__kernel void
csr_integrate_padded( const __global float *weights,
const __global float *coefs,
const __global int *row_ind,
const __global int *col_ptr,
const int do_dummy,
const float dummy,
__global float *outData,
__global float *outCount,
__global float *outMerge
)
{
int thread_id_loc = get_local_id(0);
int bin_num = get_group_id(0); // each workgroup of size=warp is assinged to 1 bin
int2 bin_bounds;
// bin_bounds = (int2) *(col_ptr+bin_num); // cool stuff!
bin_bounds.x = col_ptr[bin_num];
bin_bounds.y = col_ptr[bin_num+1];
float sum_data = 0.0f;
float sum_count = 0.0f;
float cd = 0.0f;
float cc = 0.0f;
float t, y;
const float epsilon = 1e-10f;
float coef, data;
int idx, k, j;
for (j=bin_bounds.x;j<bin_bounds.y;j+=WORKGROUP_SIZE)
{
k = j+thread_id_loc;
coef = coefs[k];
idx = row_ind[k];
data = weights[idx];
if( (!do_dummy) || (data!=dummy) )
{
//sum_data += coef * data;
//sum_count += coef;
//Kahan summation allows single precision arithmetics with error compensation
//http://en.wikipedia.org/wiki/Kahan_summation_algorithm
y = coef*data - cd;
t = sum_data + y;
cd = (t - sum_data) - y;
sum_data = t;
y = coef - cc;
t = sum_count + y;
cc = (t - sum_count) - y;
sum_count = t;
};//end if dummy
};//for j
/*
* parallel reduction
*/
// REMEMBER TO PASS WORKGROUP_SIZE AS A CPP DEF
__local float super_sum_data[WORKGROUP_SIZE];
__local float super_sum_data_correction[WORKGROUP_SIZE];
__local float super_sum_count[WORKGROUP_SIZE];
__local float super_sum_count_correction[WORKGROUP_SIZE];
super_sum_data[thread_id_loc] = sum_data;
super_sum_count[thread_id_loc] = sum_count;
super_sum_data_correction[thread_id_loc] = cd;
super_sum_count_correction[thread_id_loc] = cc;
barrier(CLK_LOCAL_MEM_FENCE);
float super_sum_temp = 0.0f;
int index, active_threads = WORKGROUP_SIZE;
cd = 0;
cc = 0;
while (active_threads != 1)
{
active_threads /= 2;
if (thread_id_loc < active_threads)
{
index = thread_id_loc+active_threads;
cd = super_sum_data_correction[thread_id_loc] + super_sum_data_correction[index];
super_sum_temp = super_sum_data[thread_id_loc];
y = super_sum_data[index] - cd;
t = super_sum_temp + y;
super_sum_data_correction[thread_id_loc] = (t - super_sum_temp) - y;
super_sum_data[thread_id_loc] = t;
cc = super_sum_count_correction[thread_id_loc] + super_sum_count_correction[index];
super_sum_temp = super_sum_count[thread_id_loc];
y = super_sum_count[index] - cc;
t = super_sum_temp + y;
super_sum_count_correction[thread_id_loc] = (t - super_sum_temp) - y;
super_sum_count[thread_id_loc] = t;
}
barrier(CLK_LOCAL_MEM_FENCE);
}
if (thread_id_loc == 0)
{
outData[bin_num] = super_sum_data[0];
outCount[bin_num] = super_sum_count[0];
if (outCount[bin_num] > epsilon)
outMerge[bin_num] = outData[bin_num] / outCount[bin_num];
else
outMerge[bin_num] = dummy;
}
};//end kernel
/**
* \brief Performs distortion corrections on an image using a LUT in CSR form
*
* @param weights Float pointer to global memory storing the input image.
* @param coefs Float pointer to global memory holding the coeficient part of the LUT
* @param row_ind Integer pointer to global memory holding the corresponding index of the coeficient
* @param col_ptr Integer pointer to global memory holding the pointers to the coefs and row_ind for the CSR matrix
* @param outData Float pointer to the output 1D array with the corrected image
*
*/
__kernel void
csr_integrate_dis( const __global float *weights,
const __global float *coefs,
const __global int *row_ind,
const __global int *col_ptr,
const int do_dummy,
const float dummy,
__global float *outData,
__global float *outCount,
__global float *outMerge
)
{
int thread_id_loc = get_local_id(0);
int bin_num = get_group_id(0); // each workgroup of size=warp is assinged to 1 bin
int2 bin_bounds;
// bin_bounds = (int2) *(col_ptr+bin_num); // cool stuff!
bin_bounds.x = col_ptr[bin_num];
bin_bounds.y = col_ptr[bin_num+1];
int bin_size = bin_bounds.y-bin_bounds.x;
float sum_data = 0.0f;
float cd = 0.0f;
float t, y;
float coef, data;
int idx, k, j;
for (j=bin_bounds.x;j<bin_bounds.y;j+=WORKGROUP_SIZE)
{
k = j+thread_id_loc;
if (k < bin_bounds.y) // I don't like conditionals!!
{
coef = coefs[k];
idx = row_ind[k];
data = weights[idx];
if( (!do_dummy) || (data!=dummy) )
{
//sum_data += coef * data;
//sum_count += coef;
//Kahan summation allows single precision arithmetics with error compensation
//http://en.wikipedia.org/wiki/Kahan_summation_algorithm
y = coef*data - cd;
t = sum_data + y;
cd = (t - sum_data) - y;
sum_data = t;
};//end if dummy
} //end if k < bin_bounds.y
};//for j
/*
* parallel reduction
*/
// REMEMBER TO PASS WORKGROUP_SIZE AS A CPP DEF
__local float super_sum_data[WORKGROUP_SIZE];
__local float super_sum_data_correction[WORKGROUP_SIZE];
float super_sum_temp = 0.0f;
int index, active_threads = WORKGROUP_SIZE;
if (bin_size < WORKGROUP_SIZE)
{
if (thread_id_loc < bin_size)
{
super_sum_data_correction[thread_id_loc] = cd;
super_sum_data[thread_id_loc] = sum_data;
}
else
{
super_sum_data_correction[thread_id_loc] = 0.0f;
super_sum_data[thread_id_loc] = 0.0f;
}
}
else
{
super_sum_data_correction[thread_id_loc] = cd;
super_sum_data[thread_id_loc] = sum_data;
}
barrier(CLK_LOCAL_MEM_FENCE);
cd = 0;
while (active_threads != 1)
{
active_threads /= 2;
if (thread_id_loc < active_threads)
{
index = thread_id_loc+active_threads;
super_sum_temp = super_sum_data[thread_id_loc];
y = super_sum_data[index] - cd;
t = super_sum_temp + y;
cd = (t - super_sum_temp) - y;
super_sum_data[thread_id_loc] = t;
}
barrier(CLK_LOCAL_MEM_FENCE);
}
if (thread_id_loc == 0)
{
outData[bin_num] = super_sum_data[0];
}
};//end kernel
|