/usr/share/zsh/site-functions/_xss-lock is in xss-lock 0.3.0-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 | #compdef xss-lock
function _xss-lock_arguments {
_arguments -S -s : $@ \
'(-n --notifier)'{-n,--notifier=}'[set notification command]: : _command_names -e' \
'(-l --transfer-sleep-lock)'{-l,--transfer-sleep-lock}'[pass sleep delay lock file descriptor to locker]' \
'--ignore-sleep[do not lock on suspend/hibernate]' \
'(-q --quiet -v --verbose)'{-q,--quiet}'[output only fatal errors]' \
'(-q --quiet -v --verbose)'{-v,--verbose}'[output more messages]' \
'--version[print version number and exit]' \
'(-h --help)'{-h,--help}'[print usage info and exit]'
}
function _arguments_after_locker {
if (( complete_locker_args )); then
_normal
else
_xss-lock_arguments
fi
}
integer complete_locker_args=$(( words[(i)--] < CURRENT ))
_xss-lock_arguments \
'(-):lock command: _command_names -e' \
'*::arguments: _arguments_after_locker'
|