/usr/share/perl5/Config/Model/Backend/DpkgSyntax.pm is in libconfig-model-dpkg-perl 2.090.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 | package Config::Model::Backend::DpkgSyntax ;
use strict;
use warnings;
use Mouse::Role;
use Carp;
use Config::Model::Exception ;
use Log::Log4perl qw(get_logger :levels);
use 5.20.0;
use feature qw/postderef signatures/;
no warnings qw/experimental::postderef experimental::signatures/;
use base qw/Config::Model::Backend::Any/;
my $logger = get_logger("Backend::DpkgSyntax") ;
sub parse_dpkg_file {
my $self = shift ;
my $file_path = shift;
my $fh = shift;
my $check = shift || 'yes' ;
my $comment_allowed = shift || 0 ;
my @lines = $fh->getlines ;
chomp @lines ;
$fh->close ;
$self->parse_dpkg_lines ($file_path, \@lines, $check, $comment_allowed);
}
#
# New subroutine "parse_dpkg_lines" extracted - Tue Jul 19 17:47:58 2011.
#
sub parse_dpkg_lines {
my ($self, $file_path, $lines, $check, $comment_allowed, $handle_garbage) = @_ ;
my $field;
my $store_list_ref ; # hold field data
my @comments; # hold comment data
my $store_list = [] ; # holds sections
my $key = '';
my $line_nb = 1 ;
my $section_line = 1 ;
# list of list ( $line_nb_nb, section, ... ) where section is
# [keyword,[ maybe keyword comments, .. , [ value, line_nb, altered , comment ] , ... ])
my @res ;
foreach my $l (@$lines) {
$logger->trace("Parsing $file_path line $line_nb '$l'");
if ( $l =~ /^#/) { # comment are always located before the keyword (hopefully)
if ($comment_allowed) {
my $c = $l ;
$c =~ s/#\s// ;
push @comments, $c ;
}
else {
Config::Model::Exception::Syntax->throw (
object => $self,
parsed_file => $file_path,
parsed_line => $line_nb,
message => "Comments are not allowed. (use -force option to drop comments)",
) if $check eq 'yes' ;
my $msg = "File $file_path: Dropped comment line $line_nb";
$logger->error($msg) if $check eq 'skip';
$logger->warn($msg) if $check eq 'no';
}
}
elsif ( $l =~ /^([\w\-]+)\s*:/ ) { # keyword:
my ($field,$text) = split /\s*:\s*/,$l,2 ;
$text =~ s/\s+$//;
$key = $field ;
$logger->trace("$file_path line $line_nb start new field $key with '$text'");
# @$store_list will be used in a hash, where the $field is key
# store value found, file line number, is value altered (used later, not for now)
# and comments
$store_list_ref = [ @comments, [ $text , $line_nb, '' ] ];
@comments = () ;
push @$store_list, $field, $store_list_ref ;
}
elsif ( $key and $l =~ /^\s*$/ ) { # first empty line after a section
$logger->trace("$file_path empty line $line_nb: starting new section");
$key = '';
push @res, $section_line, $store_list if @$store_list ; # don't store empty sections
$store_list = [] ;
$section_line = $line_nb + 1; # next line, will be clobbered if next line is empty
undef $store_list_ref ; # to ensure that next line contains a keyword
}
elsif ( $l =~ /^\s*$/ ) { # "extra" empty line
$handle_garbage->($l, $line_nb) if $handle_garbage ;
$logger->trace("extra empty line: skipped");
# just skip it
}
elsif ( $l =~ /^\s+\.$/) { # line with a single dot
$logger->trace("dot line: adding blank line to field $key");
_store_line_and_comments($store_list_ref,$file_path,"",$check,$line_nb, $handle_garbage, \@comments) ;
}
elsif ( $l =~ s/^\s//) { # non empty line
$logger->trace("text line: adding '$l' to field $key");
_store_line_and_comments($store_list_ref,$file_path,$l , $check,$line_nb, $handle_garbage, \@comments);
}
elsif ($handle_garbage) {
$logger->trace("storing garbage in line $line_nb: $l");
$handle_garbage->($l, $line_nb, \@comments) ;
}
else {
my $msg = "DpkgSyntax error: Invalid line (missing ':' ?) : $l" ;
Config::Model::Exception::Syntax -> throw (
message => $msg,
parsed_file => $file_path,
parsed_line => $line_nb
) if $check eq 'yes' ;
$logger->error($msg) if $check eq 'skip';
}
$line_nb++;
}
# store last section if not empty
push @res, $section_line, $store_list if @$store_list;
if ($logger->is_debug ) {
for (my $i = 0 ; 2*$i < $#res ; $i++ ) {
my $l = $res[$i*2];
my $s = $res[$i*2 + 1];
my %section_data = @$s;
$logger->debug("Parse result section $i, found:") ;
foreach my $key (keys %section_data) {
my $data = $section_data{$key};
$logger->debug( "$key: ". $data->[0][0]. (@$data > 1 ? ' ...':'')) ;
}
}
}
$logger->warn("No section found in file $file_path") unless @res ;
return wantarray ? @res : \@res ;
}
sub _store_line_and_comments ($store_ref,$file_path,$line,$check,$line_nb, $handle_garbage, $comments) {
if (defined $store_ref) {
push $store_ref->@* , [ $line , $line_nb, '', $comments->@* ]
}
elsif ($handle_garbage) {
$logger->trace("storing garbage in line $line_nb: $line");
$handle_garbage->($line, $line_nb, $comments->@*) ;
}
else {
my $msg = "Did not find a keyword before: '$line''";
Config::Model::Exception::Syntax -> throw (
message => $msg,
parsed_file => $file_path,
parsed_line => $line_nb
) if $check eq 'yes' ;
$logger->error($msg) if $check eq 'skip';
}
$comments->@* = (); # reset comments, they are now stored
}
# input is [ section [ keyword => value | value_list_ref ] ]
sub write_dpkg_file {
my ($self, $ioh, $array_ref,$list_sep) = @_ ;
my @lines = $self->format_dpkg_section(shift @$array_ref,$list_sep) ;
foreach my $section (@$array_ref) {
push @lines, '', $self->format_dpkg_section($section,$list_sep) ;
}
$ioh->print ( join("\n", @lines ), "\n");
}
# TODO: also rework coyright and dpkgpatch to cope with new data structure
# input is [ may_be_comment, keyword => value | value_list_ref, ... ]
sub format_dpkg_section {
my ($self, $array_ref,$list_sep) = @_ ;
my @lines ;
my $i = 0;
foreach (my $i=0; $i < @$array_ref; $i += 2 ) {
while ($array_ref->[$i] =~ /^#/) {
# print comment
push @lines, $array_ref->[$i++] ;
}
my $name = $array_ref->[$i] ;
my $value = $array_ref->[$i + 1];
if (ref ($value)) {
push @lines, $self->format_dpkg_list($name, $value, $list_sep) ;
}
else {
push @lines, $self->format_dpkg_text($name, $value) ;
}
}
return @lines;
}
# since list_sep may contain a \n or not, the list is formatted as a string
sub format_dpkg_list ($self, $name, $value_list_ref, $list_sep) {
my $result = '';
my $sep = $list_sep // ",\n" ;
my $pad = $sep =~ /\n$/ ? ' ' x (length ($name) + 2) : '' ;
my $idx = 0;
foreach my $item ($value_list_ref->@*) {
my ($list_elt, $comment_elt) = ref($item) ? $item->@* : ($item);
if ($comment_elt and $sep !~ /\n/) {
$logger->error("Cannot store comment when list is stored on a single line\nDropping '$comment_elt'");
$comment_elt = '';
}
if ($idx == 0 and $comment_elt) {
$result .= $self->format_label_line($name, '');
$result .= $comment_elt . "\n" . $pad . $list_elt ;
}
elsif ($idx == 0) {
$result .= $self->format_label_line($name, $list_elt) ;
}
else {
$result .= $comment_elt."\n" if $comment_elt;
$result .= $pad.$list_elt;
}
$result .= $sep unless $idx == $value_list_ref->$#*;
$idx++ ;
}
return $result;
}
sub write_dpkg_text {
my ($self, $ioh, $text) = @_ ;
$ioh->print ( join("\n", $self->format_dpkg_text('',$text)), "\n" );
}
sub format_dpkg_text {
my ($self, $name, $text) = @_ ;
return unless $text ;
my @lines = split /\n/,$text ;
my $label_line = $self->format_label_line($name, shift @lines);
foreach (@lines) {
s/^/ /gm; # insert leading white space
s/^\s*$/ ./gm ; # insert dot for empty lines
}
return ($label_line, @lines) ;
}
sub format_label_line {
my ($self, $name, $v0) = @_ ;
return $v0 unless $name;
my $label_line = $name.":";
$label_line .= ' '.$v0 if $v0 =~ /\S/;
return $label_line;
}
1;
__END__
=head1 NAME
Config::Model::Backend::DpkgSyntax - Role to read and write files with Dpkg syntax
=head1 SYNOPSIS
With a dpkg file containing:
Name: Foo
Version: 1.2
# section comment
Name: Bar
# data comment
Version: 1.3
Files: file1,
# inline comment
file2
Description: A very
.
long description
Parse the file with:
package MyParser ;
use strict;
use warnings;
use Log::Log4perl qw(:easy);
Log::Log4perl->easy_init($WARN);
# load role
use Mouse ;
with 'Config::Model::Backend::DpkgSyntax';
package main ;
use IO::File;
use Data::Dumper;
my $file = 'examples/dpkg-test'; # replace with any file name
my $fh = IO::File->new();
$fh->open("< $file");
my $parser = MyParser->new() ;
my $data = $parser->parse_dpkg_file($file, $fh, 'yes', 1);
$fh->close;
print Dumper $data;
Data contains:
[
1, # section 1 found in line 1
[
'Name', # first parameter
[
'section comment',
[
'Foo', # first parameter data
1, # also found in line 1
'' # currently always empty
]
],
'Version', [ 'data comment', ['1.2', 2, '']]
], # end of section 1
4, # section 2 found in line 4
[
'Name', [['Bar', 5, '']],
'Version', [['1.3', 7, '']],
'Files', # param with 2 lines
[
['file1,', 8, ''],
[' file2', 10, '', 'inline comment'] # padding is kept
],
'Description', # param with 3 lines
[
['A very', 11, ''],
['', 12, ''], # empty line, note: dot was removed
['long description', 13, '']
]
] # end of section 2
]; # end of data
To write Dpkg file back:
package MyParser ;
use strict;
use warnings;
use 5.20.1;
use Log::Log4perl qw(:easy);
Log::Log4perl->easy_init($WARN);
# load role
use Mouse ;
with 'Config::Model::Backend::DpkgSyntax';
package main ;
use IO::File;
use Data::Dumper;
# note: the structure is different compared to the one returned by
# the parser (no line number)
my $data = [
[ '# section comment', qw/Name Foo/, '# data comment', qw/Version 1.2/ ],
[
qw/Name Bar Version 1.3/ ,
Files => [qw/file1/, [ 'file2' , '# inline comment'] ] ,
Description => "A very\n\nlong description"
]
];
my $parser = MyParser->new() ;
my $fhw = IO::File->new ;
$fhw -> open ( 'examples/dpkg-new' ,'>',"," ) ;
$parser->write_dpkg_file($fhw,$data) ;
$fhw->close;
=head1 DESCRIPTION
This module is a Moose role to read and write dpkg control files.
Debian control file are read and transformed in a structure
matching the control file. The top level list of a list of section.
Each section is mapped to a structure containing the parameter names and values,
comments and line numbers. See the synopsis for an example.
Note: The description is changed into a paragraph without the Dpkg
syntax idiosyncrasies. The leading white space is removed and the
single dot is transformed in to a "\n". These characters are restored
when the file is written back.
Last not but not least, this module could re-used outside of
C<Config::Model> with some small modifications in exception
handing. Ask the author if you want this module shipped in its own
distribution.
=head1
=head2 parse_dpkg_file
Parameters: C<( file_path, file_handle, [ check, [ comment_allowed ]] )>
Read a control file from C<file_handle> and returns a nested list (or
a list ref) containing data from the file.
See sysnopsis for the returned structure.
C<check> is C<yes>, C<skip> or C<no> (default C<yes>).
C<comment_allowed> is boolean (default 0)
=head2 parse_dpkg_lines
Parameters: C< ( file_path, lines, check, comment_allowed ) >
Parse the dpkg date from lines (which is an array ref) and return a data
structure like L<parse_dpkg_file>.
=head2 write_dpkg_file
Parameters C< ( io_handle, list_ref, list_sep ) >
Munge the passed list ref into a string compatible with control files
and write it in the passed file handle.
The input is a list of list in a form similar to the one generated by
L<parse_dpkg_file>. See the synopsis for an example
List items (like C<Depends> field in C<debian/control>) are joined
with the value C<list_sep> before being written. Values are aligned in
case of multi-line output of a list. Default value of C<list_sep> is "C<,\n>"
For instance the following code :
my $ref = [ [ Foo => 'foo value' , Bar => [ 'v1', 'v2' ] ];
write_dpkg_file ( $ioh, $ref, ', ' )
yields:
Foo: foo value
Bar: v1, v2
Here's an example using default C<$sep_list>:
write_dpkg_file ( $ioh, $ref )
yields:
Foo: foo value
Bar: v1,
v2
=head1 AUTHOR
Dominique Dumont, (ddumont at cpan dot org)
=head1 SEE ALSO
L<Config::Model>,
L<Config::Model::BackendMgr>,
L<Config::Model::Backend::Any>,
=cut
|