libmoose-autobox-perl 0.16-1 / usr / share / perl5 / Moose / Autobox / Code.pm

This file is indexed.

/usr/share/perl5/Moose/Autobox/Code.pm is in libmoose-autobox-perl 0.16-1.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
package Moose::Autobox::Code;
# ABSTRACT: the Code role
use Moose::Role 'with';
use Moose::Autobox;
use namespace::autoclean;

our $VERSION = '0.16';

with 'Moose::Autobox::Ref';

sub curry {
    my ($f, @a) = @_;
    return sub { $f->(@a, @_) }
}

sub rcurry {
    my ($f, @a) = @_;
    return sub { $f->(@_, @a) }
}

sub compose {
    my ($f, $f2, @rest) = @_;
    return $f if !$f2;
    return (sub { $f2->($f->(@_)) })->compose(@rest);
}

sub disjoin {
    my ($f, $f2) = @_;
    return sub { $f->(@_) || $f2->(@_) }
}

sub conjoin {
    my ($f, $f2) = @_;
    return sub { $f->(@_) && $f2->(@_) }
}

# fixed point combinators

sub u {
    my $f = shift;
    sub { $f->($f, @_) };
}

sub y {
    my $f = shift;
    (sub { my $h = shift; sub { $f->(($h->u)->())->(@_) } }->u)->();
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Moose::Autobox::Code - the Code role

=head1 VERSION

version 0.16

=head1 SYNOPSIS

  use Moose::Autobox;

  my $adder = sub { $_[0] + $_[1] };
  my $add_2 = $adder->curry(2);

  $add_2->(2); # returns 4

  # create a recursive subroutine
  # using the Y combinator
  *factorial = sub {
      my $f = shift;
      sub {
          my $n = shift;
          return 1 if $n < 2;
          return $n * $f->($n - 1);
      }
  }->y;

  factorial(10) # returns 3628800

=head1 DESCRIPTION

This is a role to describe operations on the Code type.

=head1 METHODS

=over 4

=item C<curry (@values)>

=item C<rcurry (@values)>

=item C<conjoin (\&sub)>

=item C<disjoin (\&sub)>

=item C<compose (@subs)>

This will take a list of C<@subs> and compose them all into a single
subroutine where the output of one sub will be the input of another.

=item C<y>

=for :stopwords combinator

This implements the Y combinator.

=item C<u>

This implements the U combinator.

=back

=over 4

=item C<meta>

=back

=head1 SEE ALSO

=over 4

=item L<http://en.wikipedia.org/wiki/Fixed_point_combinator>

=item L<http://blade.nagaokaut.ac.jp/cgi-bin/scat.rb/ruby/ruby-talk/20469>

=back

=head1 SUPPORT

Bugs may be submitted through L<the RT bug tracker|https://rt.cpan.org/Public/Dist/Display.html?Name=Moose-Autobox>
(or L<bug-Moose-Autobox@rt.cpan.org|mailto:bug-Moose-Autobox@rt.cpan.org>).

There is also a mailing list available for users of this distribution, at
L<http://lists.perl.org/list/moose.html>.

There is also an irc channel available for users of this distribution, at
L<C<#moose> on C<irc.perl.org>|irc://irc.perl.org/#moose>.

=head1 AUTHOR

Stevan Little <stevan.little@iinteractive.com>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2006 by Infinity Interactive, Inc.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

APT Browse - Built by Thomas Orozco.