/usr/share/acl2-4.3/books/str/iprefixp.lisp is in acl2-books-source 4.3-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 | ; ACL2 String Library
; Copyright (C) 2009-2010 Centaur Technology
;
; Contact:
; Centaur Technology Formal Verification Group
; 7600-C N. Capital of Texas Highway, Suite 300, Austin, TX 78731, USA.
; http://www.centtech.com/
;
; This program is free software; you can redistribute it and/or modify it under
; the terms of the GNU General Public License as published by the Free Software
; Foundation; either version 2 of the License, or (at your option) any later
; version. This program is distributed in the hope that it will be useful but
; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
; FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
; more details. You should have received a copy of the GNU General Public
; License along with this program; if not, write to the Free Software
; Foundation, Inc., 51 Franklin Street, Suite 500, Boston, MA 02110-1335, USA.
;
; Original author: Jared Davis <jared@centtech.com>
(in-package "STR")
(include-book "ieqv")
(include-book "unicode/prefixp" :dir :system)
(local (include-book "arithmetic"))
(defund iprefixp (x y)
":Doc-Section Str
Case-insensitive character-list prefix test~/
~c[(iprefixp x y)] determines whether one character list is a prefix of another,
where each character is tested using ~il[str::ichareqv].~/
~l[str::istrprefixp]"
(declare (xargs :guard (and (character-listp x)
(character-listp y))))
(if (consp x)
(and (consp y)
(ichareqv (car x) (car y))
(iprefixp (cdr x) (cdr y)))
t))
(defthm iprefixp-when-not-consp-left
(implies (not (consp x))
(iprefixp x y))
:hints(("Goal" :in-theory (enable iprefixp))))
(defthm iprefixp-of-cons-left
(equal (iprefixp (cons a x) y)
(and (consp y)
(ichareqv a (car y))
(iprefixp x (cdr y))))
:hints(("Goal" :in-theory (enable iprefixp))))
(defthm iprefixp-when-not-consp-right
(implies (not (consp y))
(equal (iprefixp x y)
(not (consp x))))
:hints(("Goal" :induct (len x))))
(defthm iprefixp-of-cons-right
(equal (iprefixp x (cons a y))
(if (consp x)
(and (ichareqv (car x) a)
(iprefixp (cdr x) y))
t)))
(defthm iprefixp-of-list-fix-left
(equal (iprefixp (list-fix x) y)
(iprefixp x y))
:hints(("Goal" :in-theory (enable iprefixp))))
(defthm iprefixp-of-list-fix-right
(equal (iprefixp x (list-fix y))
(iprefixp x y))
:hints(("Goal" :in-theory (enable iprefixp))))
(defcong icharlisteqv equal (iprefixp x y) 1
:hints(("Goal" :in-theory (enable iprefixp))))
(defcong icharlisteqv equal (iprefixp x y) 2
:hints(("Goal" :in-theory (enable iprefixp))))
(defthm iprefixp-when-prefixp
(implies (prefixp x y) (iprefixp x y))
:hints(("Goal" :in-theory (enable iprefixp))))
|