/usr/share/acl2-4.3/books/str/suffixp.lisp is in acl2-books-source 4.3-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 | ; ACL2 String Library
; Copyright (C) 2009-2010 Centaur Technology
;
; Contact:
; Centaur Technology Formal Verification Group
; 7600-C N. Capital of Texas Highway, Suite 300, Austin, TX 78731, USA.
; http://www.centtech.com/
;
; This program is free software; you can redistribute it and/or modify it under
; the terms of the GNU General Public License as published by the Free Software
; Foundation; either version 2 of the License, or (at your option) any later
; version. This program is distributed in the hope that it will be useful but
; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
; FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
; more details. You should have received a copy of the GNU General Public
; License along with this program; if not, write to the Free Software
; Foundation, Inc., 51 Franklin Street, Suite 500, Boston, MA 02110-1335, USA.
;
; Original author: Jared Davis <jared@centtech.com>
(in-package "STR")
(include-book "strprefixp")
(local (include-book "make-event/assert" :dir :system))
(local (defthm prefixp-reflexive
(prefixp x x)
:hints(("Goal" :in-theory (enable prefixp)))))
(local (defthm crock
(implies (and (equal (len x) (len y))
(true-listp x)
(true-listp y))
(equal (prefixp x y)
(equal x y)))
:hints(("Goal" :in-theory (enable prefixp)))))
(local (defthm len-of-nthcdr
(implies (and (natp n)
(<= n (len x)))
(equal (len (nthcdr n x))
(- (len x) n)))
:hints(("Goal" :in-theory (enable nthcdr)))))
(defund strsuffixp (x y)
":Doc-Section Str
Case-sensitive string suffix test~/
~c[(strsuffixp x y)] determines if the string x is a suffix of the string y,
in a case-sensitive manner.
Logically, we ask whether |x| < |y|, and whether
~bv[]
(nthcdr (- |y| |x|) (coerce x 'list))
==
(coerce y 'list)
~ev[]
but we use a more efficient execution to avoid coercing the strings.~/~/"
(declare (xargs :guard (and (stringp x)
(stringp y))))
(let* ((xlen (length x))
(ylen (length y)))
(and (<= xlen ylen)
(mbe :logic
(equal (nthcdr (- ylen xlen) (coerce y 'list))
(coerce x 'list))
:exec
(strprefixp-impl x y 0 (- ylen xlen) xlen ylen)))))
(local
(progn
(assert! (strsuffixp "" ""))
(assert! (strsuffixp "" "foo"))
(assert! (strsuffixp "o" "foo"))
(assert! (strsuffixp "oo" "foo"))
(assert! (not (strsuffixp "ooo" "foo")))
(assert! (not (strsuffixp "fo" "foo")))
(assert! (strsuffixp "foo" "foo"))))
|