/usr/share/perl5/Algorithm/CheckDigits/M11_009.pm is in libalgorithm-checkdigits-perl 0.50-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 | package Algorithm::CheckDigits::M11_009;
use 5.006;
use strict;
use warnings;
use integer;
our @ISA = qw(Algorithm::CheckDigits);
my @weight = ( 2, 7, 6, 5, 4, 3, 2 );
my @keys = ('', 'A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', 'Z', 'J' );
sub new {
my $proto = shift;
my $type = shift;
my $class = ref($proto) || $proto;
my $self = bless({}, $class);
$self->{type} = lc($type);
return $self;
} # new()
sub is_valid {
my ($self,$number) = @_;
if ($number =~ /^([fgst])(\d{7})([a-jz])$/i) {
return (uc($3) eq $self->_compute_checkdigits($2));
}
return ''
} # is_valid()
sub complete {
my ($self,$number) = @_;
if($number =~ /^([fgst])(\d{7})$/i) {
return $1 . $2 . $self->_compute_checkdigits($2);
}
return '';
} # complete()
sub basenumber {
my ($self,$number) = @_;
return "$1$2" if( $number =~ /^([fgst])(\d{7})([a-jz])$/i
and uc($3) eq $self->_compute_checkdigits($2));
return '';
} # basenumber()
sub checkdigit {
my ($self,$number) = @_;
if ($number =~ /^([fgst])(\d{7})([a-jz])$/i) {
return $self->_compute_checkdigits($2);
}
return undef;
} # checkdigit()
sub _compute_checkdigits {
my $self = shift;
my @digits = split(//,shift);
my $sum = 0;
for (my $i = 0; $i <= $#digits; $i++) {
$sum += $weight[$i] * $digits[$i];
}
$sum %= 11;
return $keys[11 - $sum];
} # _compute_checkdigit()
# Preloaded methods go here.
1;
__END__
=head1 NAME
CheckDigits::M11_009 - compute check digits NRIC (SG)
=head1 SYNOPSIS
use Algorithm::CheckDigits;
$nric = CheckDigits('nric_sg');
if ($nric->is_valid('S1234567D')) {
# do something
}
$cn = $nric->complete('S1234567');
# $cn = 'S1234567D'
$cd = $nric->checkdigit('S1234567D');
# $cd = 'D'
$bn = $nric->basenumber('S1234567D');
# $bn = 'S1234567';
=head1 DESCRIPTION
=head2 ALGORITHM
=over 4
=item 1
Beginning left every digit is weighted with 2, 7, 6, 5, 4, 3, 2
=item 2
The weighted digits are added.
=item 3
The sum from step 2 is taken modulo 11.
=item 4
The checkdigit is 11 minus the sum from step 3 converted to a
character according to the following table:
@cd = ('','A','B','C','D','E','F','G','H','I','Z','J', );
=back
=head2 METHODS
=over 4
=item is_valid($number)
Returns true only if C<$number> consists solely of numbers and hyphens
and the two digits in the middle
are valid check digits according to the algorithm given above.
Returns false otherwise,
=item complete($number)
The check digit for C<$number> is computed and inserted into the
middle of C<$number>.
Returns the complete number with check digit or '' if C<$number>
does not consist solely of digits, hyphens and spaces.
=item basenumber($number)
Returns the basenumber of C<$number> if C<$number> has a valid check
digit.
Return '' otherwise.
=item checkdigit($number)
Returns '' if C<$number> is valid.
Return undef otherwise.
=back
=head2 EXPORT
None by default.
=head1 AUTHOR
Mathias Weidner, E<lt>mathias@weidner.in-bad-schmiedeberg.deE<gt>
=head1 SEE ALSO
L<perl>,
L<CheckDigits>,
F<www.pruefziffernberechnung.de>,
=cut
|