/usr/share/perl5/Dist/Zilla/Plugin/PkgDist.pm is in libdist-zilla-perl 6.010-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 | package Dist::Zilla::Plugin::PkgDist 6.010;
# ABSTRACT: add a $DIST to your packages
use Moose;
with(
'Dist::Zilla::Role::FileMunger',
'Dist::Zilla::Role::FileFinderUser' => {
default_finders => [ ':InstallModules', ':ExecFiles' ],
},
'Dist::Zilla::Role::PPI',
);
use namespace::autoclean;
#pod =head1 DESCRIPTION
#pod
#pod This plugin will add a line like the following to each package in each Perl
#pod module or program (more or less) within the distribution:
#pod
#pod { our $DIST = 'My-CPAN-Dist'; } # where 'My-CPAN-Dist' is your dist name
#pod
#pod It will skip any package declaration that includes a newline between the
#pod C<package> keyword and the package name, like:
#pod
#pod package
#pod Foo::Bar;
#pod
#pod This sort of declaration is also ignored by the CPAN toolchain, and is
#pod typically used when doing monkey patching or other tricky things.
#pod
#pod =cut
sub munge_files {
my ($self) = @_;
$self->munge_file($_) for @{ $self->found_files };
}
sub munge_file {
my ($self, $file) = @_;
# XXX: for test purposes, for now! evil! -- rjbs, 2010-03-17
return if $file->name =~ /^corpus\//;
return if $file->name =~ /\.t$/i;
return $self->munge_perl($file) if $file->name =~ /\.(?:pm|pl)$/i;
return $self->munge_perl($file) if $file->content =~ /^#!(?:.*)perl(?:$|\s)/;
return;
}
sub munge_perl {
my ($self, $file) = @_;
my $dist_name = $self->zilla->name;
my $document = $self->ppi_document_for_file($file);
return unless my $package_stmts = $document->find('PPI::Statement::Package');
if ($self->document_assigns_to_variable($document, '$DIST')) {
$self->log([ 'skipping %s: assigns to $DIST', $file->name ]);
return;
}
my %seen_pkg;
for my $stmt (@$package_stmts) {
my $package = $stmt->namespace;
if ($seen_pkg{ $package }++) {
$self->log([ 'skipping package re-declaration for %s', $package ]);
next;
}
if ($stmt->content =~ /package\s*\n\s*\Q$package/) {
$self->log([ 'skipping private package %s', $package ]);
next;
}
# the \x20 hack is here so that when we scan *this* document we don't find
# an assignment to version; it shouldn't be needed, but it's been annoying
# enough in the past that I'm keeping it here until tests are better
my $perl = "{\n \$$package\::DIST\x20=\x20'$dist_name';\n}\n";
my $dist_doc = PPI::Document->new(\$perl);
my @children = $dist_doc->schildren;
$self->log_debug([
'adding $DIST assignment to %s in %s',
$package,
$file->name,
]);
# the extra whitespace element ensures we don't swallow up any blanks
# lines after 'package ...' in the source file that PkgVersion warns about
# if it's missing.
Carp::carp('error inserting $DIST in ' . $file->name)
unless $stmt->add_element( PPI::Token::Whitespace->new("\n") )
and $stmt->insert_after($children[0]->clone)
and $stmt->insert_after( PPI::Token::Whitespace->new("\n") );
}
# the document is no longer correct; it must be reparsed before it can be used again
$file->content($document->serialize);
}
__PACKAGE__->meta->make_immutable;
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dist::Zilla::Plugin::PkgDist - add a $DIST to your packages
=head1 VERSION
version 6.010
=head1 DESCRIPTION
This plugin will add a line like the following to each package in each Perl
module or program (more or less) within the distribution:
{ our $DIST = 'My-CPAN-Dist'; } # where 'My-CPAN-Dist' is your dist name
It will skip any package declaration that includes a newline between the
C<package> keyword and the package name, like:
package
Foo::Bar;
This sort of declaration is also ignored by the CPAN toolchain, and is
typically used when doing monkey patching or other tricky things.
=head1 AUTHOR
Ricardo SIGNES 😏 <rjbs@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2017 by Ricardo SIGNES.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|