/usr/share/augeas/lenses/dist/modprobe.aug is in augeas-lenses 0.10.0-0ubuntu4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 | (*
Module: Modprobe
Parses /etc/modprobe.conf and /etc/modprobe.d/*
Original Author: David Lutterkort <lutter@redhat.com>
Author: Raphael Pinson <raphink@gmail.com>
About: Reference
This lens tries to keep as close as possible to `man 5 modprobe.conf` where possible.
About: License
This file is licenced under the LGPLv2+, like the rest of Augeas.
About: Lens Usage
To be documented
About: Configuration files
This lens applies to /etc/modprobe.conf and /etc/modprobe.d/*. See <filter>.
*)
module Modprobe =
autoload xfm
(************************************************************************
* Group: USEFUL PRIMITIVES
*************************************************************************)
(* View: comment *)
let comment = Util.comment
(* View: empty *)
let empty = Util.empty
(* View: sep_space *)
let sep_space = del /([ \t]|(\\\\\n))+/ " "
(* View: sto_no_spaces *)
let sto_no_spaces = store /[^# \t\n\\\\]+/
(* View: sto_to_eol *)
let sto_to_eol = store /[^# \t\n\\\\][^#\n\\\\]*[^# \t\n\\\\]|[^# \t\n\\\\]/
(* View: alias *)
let alias =
let modulename = [ label "modulename" . sto_no_spaces ] in
Build.key_value_line_comment "alias" sep_space
(sto_no_spaces . sep_space . modulename)
comment
(************************************************************************
* Group: ENTRY TYPES
*************************************************************************)
(* View: options *)
let options =
let opt_value = /[^#" \t\n\\\\]+|"[^#"\n\\\\]*"/ in
let option = [ key Rx.word . (Util.del_str "=" . store opt_value)? ] in
[ key "options" . sep_space . sto_no_spaces
. (sep_space . option)* . Util.comment_or_eol ]
(* View: install_remove *)
let kv_line_command (kw:regexp) =
let command = [ label "command" . sto_to_eol ] in
[ key kw . sep_space . sto_no_spaces
. sep_space . command . Util.comment_or_eol ]
(* View: blacklist *)
let blacklist = Build.key_value_line_comment "blacklist" sep_space
sto_no_spaces
comment
(* View: config *)
let config = Build.key_value_line_comment "config" sep_space
(store /binary_indexes|yes|no/)
comment
(* View: entry *)
let entry = alias
| options
| kv_line_command /install|remove/
| blacklist
| config
(************************************************************************
* Group: LENS AND FILTER
*************************************************************************)
(* View: lns *)
let lns = (comment|empty|entry)*
(* View: filter *)
let filter = (incl "/etc/modprobe.conf") .
(incl "/etc/modprobe.d/*").
(incl "/etc/modprobe.conf.local").
Util.stdexcl
let xfm = transform lns filter
|