/usr/share/perl5/Dist/Zilla/Plugin/Encoding.pm is in libdist-zilla-perl 5.008-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 | package Dist::Zilla::Plugin::Encoding;
{
$Dist::Zilla::Plugin::Encoding::VERSION = '5.008';
}
# ABSTRACT: set the encoding of arbitrary files
use Moose;
with 'Dist::Zilla::Role::EncodingProvider';
use namespace::autoclean;
sub mvp_multivalue_args { qw(filenames matches) }
sub mvp_aliases { return { filename => 'filenames', match => 'matches' } }
has encoding => (
is => 'ro',
isa => 'Str',
required => 1,
);
has filenames => (
is => 'ro',
isa => 'ArrayRef',
default => sub { [] },
);
has matches => (
is => 'ro',
isa => 'ArrayRef',
default => sub { [] },
);
sub set_file_encodings {
my ($self) = @_;
# never match (at least the filename characters)
my $matches_regex = qr/\000/;
$matches_regex = qr/$matches_regex|$_/ for @{$self->matches};
# \A\Q$_\E should also handle the `eq` check
$matches_regex = qr/$matches_regex|\A\Q$_\E/ for @{$self->filenames};
for my $file (@{$self->zilla->files}) {
next unless $file->name =~ $matches_regex;
$self->log_debug([
'setting encoding of %s to %s',
$file->name,
$self->encoding,
]);
$file->encoding($self->encoding);
}
return;
}
__PACKAGE__->meta->make_immutable;
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dist::Zilla::Plugin::Encoding - set the encoding of arbitrary files
=head1 VERSION
version 5.008
=head1 SYNOPSIS
This plugin allows you to explicitly set the encoding on some files in your
distribution. You can either specify the exact set of files (with the
"filenames" parameter) or provide the regular expressions to check (using
"match").
In your F<dist.ini>:
[Encoding]
encoding = Latin-3
filename = t/esperanto.t ; this file is Esperanto
match = ^t/urkish/ ; these are all Turkish
=head1 ATTRIBUTES
=head2 encoding
This is the encoding to set on the selected files.
=head2 filenames
This is an arrayref of filenames to have their encoding set.
=head2 matches
This is an arrayref of regular expressions. Any file whose name matches one of
these regex will have its encoding set.
=head1 AUTHOR
Ricardo SIGNES <rjbs@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2013 by Ricardo SIGNES.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|