/usr/share/perl5/Dist/Zilla/Role/File.pm is in libdist-zilla-perl 5.008-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 | package Dist::Zilla::Role::File;
{
$Dist::Zilla::Role::File::VERSION = '5.008';
}
# ABSTRACT: something that can act like a file
use Moose::Role;
use Moose::Util::TypeConstraints;
use Try::Tiny;
use namespace::autoclean;
with 'Dist::Zilla::Role::StubBuild';
has name => (
is => 'rw',
isa => 'Str', # Path::Class::File?
required => 1,
);
has added_by => (
is => 'ro',
writer => '_set_added_by',
isa => 'Str',
);
my $safe_file_mode = subtype(
as 'Int',
where { not( $_ & 0002) },
message { "file mode would be world-writeable" }
);
has mode => (
is => 'rw',
isa => $safe_file_mode,
default => 0644,
);
requires 'encoding';
requires 'content';
requires 'encoded_content';
sub is_bytes {
my ($self) = @_;
return $self->encoding eq 'bytes';
}
sub _encode {
my ($self, $text) = @_;
my $enc = $self->encoding;
if ( $self->is_bytes ) {
return $text; # XXX hope you were right that it really was bytes
}
else {
require Encode;
my $bytes =
try { Encode::encode($enc, $text, Encode::FB_CROAK()) }
catch { $self->_throw("encode $enc" => $_) };
return $bytes;
}
}
sub _decode {
my ($self, $bytes) = @_;
my $enc = $self->encoding;
if ( $self->is_bytes ) {
$self->_throw(decode => "Can't decode text from 'bytes' encoding");
}
else {
require Encode;
my $text =
try { Encode::decode($enc, $bytes, Encode::FB_CROAK()) }
catch { $self->_throw("decode $enc" => $_) };
return $text;
}
}
sub _throw {
my ($self, $op, $msg) = @_;
my ($name, $added_by) = map {; $self->$_ } qw/name added_by/;
confess(
"Could not $op $name; $added_by; error was: $msg"
);
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dist::Zilla::Role::File - something that can act like a file
=head1 VERSION
version 5.008
=head1 DESCRIPTION
This role describes a file that may be written into the shipped distribution.
=head1 ATTRIBUTES
=head2 name
This is the name of the file to be written out.
=head2 added_by
This is a string describing when and why the file was added to the
distribution. It will generally be set by a plugin implementing the
L<FileInjector|Dist::Zilla::Role::FileInjector> role.
=head2 mode
This is the mode with which the file should be written out. It's an integer
with the usual C<chmod> semantics. It defaults to 0644.
=head1 METHODS
=head2 is_bytes
Returns true if the C<encoding> is bytes. When true, accessing
C<content> will be an error.
=head1 AUTHOR
Ricardo SIGNES <rjbs@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2013 by Ricardo SIGNES.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|