/usr/share/unity8/Dash/Previews/PreviewAudioPlayback.qml is in unity8-common 8.12+16.04.20160401-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 | /*
* Copyright (C) 2014,2015 Canonical, Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3
import Dash 0.1
/*! \brief Preview widget for audio tracks.
This widget shows tracks contained in widgetData["tracks"], each of which should be of the form:
\code{.json}
{
"source" "uri://to/file",
"title": "Title",
"subtitle": "Subtitle", // optional
"length": 125 // in seconds
}
\endcode
*/
PreviewWidget {
id: root
implicitHeight: childrenRect.height
Column {
anchors { left: parent.left; right: parent.right }
visible: trackRepeater.count > 0
Repeater {
id: trackRepeater
objectName: "trackRepeater"
model: root.widgetData["tracks"]
delegate: Item {
id: trackItem
objectName: "trackItem" + index
readonly property url sourceUrl: modelData["source"]
readonly property bool isPlayingItem: AudioUrlComparer.compare(sourceUrl, DashAudioPlayer.currentSource)
anchors { left: parent.left; right: parent.right }
height: units.gu(5)
Row {
id: trackRow
readonly property int column1Width: units.gu(3)
readonly property int column2Width: width - (2 * spacing) - column1Width - column3Width
readonly property int column3Width: units.gu(4)
anchors.verticalCenter: parent.verticalCenter
width: parent.width
spacing: units.gu(1)
Button {
objectName: "playButton"
width: trackRow.column1Width
height: width
iconSource: DashAudioPlayer.playing && trackItem.isPlayingItem ? "image://theme/media-playback-pause" : "image://theme/media-playback-start"
activeFocusOnPress: false
// Can't be "transparent" or "#00xxxxxx" as the button optimizes away the surrounding shape
// FIXME when this is resolved: https://bugs.launchpad.net/ubuntu-ui-toolkit/+bug/1251685
color: "#01000000"
onClicked: {
if (trackItem.isPlayingItem) {
if (DashAudioPlayer.playing) {
DashAudioPlayer.pause();
} else if (DashAudioPlayer.paused) {
DashAudioPlayer.play();
}
} else {
var playlist = [];
for (var i = 0; i < trackRepeater.count; ++i) {
playlist.push(trackRepeater.itemAt(i).sourceUrl);
}
DashAudioPlayer.playSource(sourceUrl, playlist);
}
}
}
Item {
anchors.verticalCenter: parent.verticalCenter
width: parent.column2Width
height: trackSubtitleLabel.visible ? trackTitleLabel.height + trackSubtitleLabel.height : trackTitleLabel.height
Label {
id: trackTitleLabel
objectName: "trackTitleLabel"
anchors { top: parent.top; left: parent.left; right: parent.right }
opacity: 0.9
color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
fontSize: "small"
horizontalAlignment: Text.AlignLeft
text: modelData["title"]
elide: Text.ElideRight
}
Label {
id: trackSubtitleLabel
objectName: "trackSubtitleLabel"
anchors { top: trackTitleLabel.bottom; left: parent.left; right: parent.right }
visible: text !== ""
opacity: 0.9
color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
font.weight: Font.Light
fontSize: "small"
horizontalAlignment: Text.AlignLeft
text: modelData["subtitle"] || ""
elide: Text.ElideRight
}
AudioProgressBar {
anchors { left: parent.left; top: parent.bottom; right: parent.right }
visible: !DashAudioPlayer.stopped && trackItem.isPlayingItem && modelData["length"] > 0
source: sourceUrl
}
}
Label {
id: timeLabel
objectName: "timeLabel"
anchors.verticalCenter: parent.verticalCenter
width: parent.column3Width
opacity: 0.9
color: scopeStyle ? scopeStyle.foreground : theme.palette.normal.baseText
fontSize: "small"
horizontalAlignment: Text.AlignRight
text: DashAudioPlayer.lengthToString(modelData["length"])
}
}
}
}
}
}
|